VBAについて質問です。

どなたからも回答がなかったので、久しぶりに作ってみました。

なお、文章が一部不明だったので、次のように捉えました。

②(丸2)：「名前が若い番号から順に開いて正規表現していく。」

　→ファイル名昇順でリストに作る（処理の都合上、この処理は最後に行った）

パターン：

「素材･色 　 ：　★値★　＜ｂｒ＞の値の部分を抜き出し」

　→　キーワード　半角・全角ブランクが0-n個　：　半角・全角ブランクが0-n個　その後が値　＜ｂｒ＞　とみなした

　もし、常に★で囲まれているのであれば、パターンの(.*?)を★で囲んでください。あっ、その後に空白があってから＜ｂｒ＞であれば、そのように変更ください。

Option Explicit

Const ForReading As Integer = 1     ' FSO

Const sColFile As String = "A"  ' カラム定義
Const sColCountry As String = "B"
Const sColColor As String = "C"
Const sColSize As String = "D"

Const sCountry As String = "生産国[ 　]*：[ 　]*(.*?)<br>"
Const sColor As String = "素材･色[ 　]*：[ 　]*(.*?)<br>"
Const sSize As String = "サイズ[ 　]*：[ 　]*(.*?)<br>"


Sub SearchValue()
    
    Dim sPath As String
    Dim vName As Variant
    Dim fs As Object, ts As Object
    Dim sBuf As String
    Dim lnRow As Long
    
    Set fs = CreateObject("Scripting.FileSystemObject")
    sPath = InputBox("フォルダ名")
    If sPath = "" Then Exit Sub
    sPath = sPath & "\"
    vName = Dir(sPath & "*.txt")           ' 最初のファイル
    lnRow = 1
    Do While vName <> ""
        Set ts = fs.OpenTextFile(sPath & vName, ForReading)
        sBuf = ts.ReadAll
        ts.Close
        ' 正規表現でファイル中から探してセルへ設定
        Cells(lnRow, sColFile) = Left(vName, Len(vName) - 4)
        Cells(lnRow, sColCountry) = sReg(sBuf, sCountry)
        Cells(lnRow, sColColor) = sReg(sBuf, sColor)
        Cells(lnRow, sColSize) = sReg(sBuf, sSize)
        vName = Dir                         ' 次のファイル
        lnRow = lnRow + 1
    Loop
    
    Range(sColFile & "1" & ":" & sColSize & (lnRow - 1)).Sort _
        Key1:=Range(sColFile & "1")         '並べ替え
End Sub


Function sReg(strTrg As String, sPattern As String) As String
    Dim re As Object
    Dim mc As Object
    
    Set re = CreateObject("VBScript.RegExp")
    With re
        .Pattern = sPattern
        .MultiLine = True
        .IgnoreCase = True
        Set mc = .Execute(strTrg)
    End With
    If mc.Count >= 1 Then
        sReg = mc(0).SubMatches(0)
    Else
      sReg = ""
    End If

End Function

P.S.以前も記載しましたが、一冊VBAの本を買っておくといいと思います。