ExcelVBAでの全角と半角が混在するテキストファイル(改行無しで10MBと大容量)を読み込み、指定バイト数で区切りを入れるという文字列を処理します。

一部分だけでなくて、関係するところをまとめて質問すると良いです。

投稿された処理内容は、多分ループ内での処理だと思います。

全体のうちの部分部分の文字列をその少ない文字列ごとにstrConvで変換しているので、処理が無駄です。全体を一括で変換するようにして、処理の回数を減らしましょう。

また、文字数が多い場合、前もってバッファを用意し、MidBステートメント(※注　関数じゃないですよ)で変換するのが処理を早くする方法です。

しかし、もともとがテキストファイルであるなら、Binaryで開いて、指定バイト数分読み込み、区切り文字（改行コードとか）を追加して別ファイルに出力していく、

最後までデータを別ファイルに出力し終わったら、元のファイルを削除して、作っておいた別ファイルの名前を元のファイル名に変更する。というロジックのほうが圧倒的に速いでしょう。

urlはダミーです。

http://www

前回の回答に近いのですが、読み取り時ANSIIで取得し、StrConvでUNICODEに変換しています。

処理時間は7MBで約6秒でした。

Option Explicit
Sub 入力処理()
  Const レコード長 = 500
  Dim レコード数                As Long
  Dim レコード(レコード長 - 1) As Byte
  Dim I                     As Long
  Dim 進捗率                   As Integer
  
  Application.ScreenUpdating = False
  Open ThisWorkbook.Path & "\TEST.TXT" For Binary As #1
  レコード数 = (LOF(1) / レコード長)
  
  For I = 1 To レコード数
   進捗率 = I * 10 / レコード数
   Application.StatusBar = String(進捗率, "■") & String(10 - 進捗率, "□")
   Get #1, , レコード
   Range("A1").Offset(I - 1).NumberFormatLocal = "@"
   Range("A1").Offset(I - 1).Value = StrConv(レコード, vbUnicode)
  Next I
  Close
  Application.StatusBar = False
  Application.ScreenUpdating = True
End Sub

注）全角が500バイトの切れ目にならいとしています。

ダミー

http://q.hatena.ne.jp/1241755947

テキストファイルの中がSJISだと仮定してですが

Byte配列をつかって処理すると速いです。

http://q.hatena.ne.jp/answer

２バイト文字が割れないよう考慮してみました。

Excel2003で1秒切れます(PCの性能によりますが)

Public Sub test1()
    
    Const fileName As String = "D:\a.txt"
    Const readCount As Long = 500
    Const bufEnd As Long = readCount - 1
    Const rowMax As Long = 65536
    
    Dim i As Long
    Dim rg As Range
    Dim bf() As Byte
    Dim cx As Variant
    
    Debug.Print Now()
    
    Application.ScreenUpdating = False
    
    'データを貼り付ける範囲
    Set rg = Worksheets(1).Range("A1:A" & rowMax)
    rg.Clear
    rg.NumberFormatLocal = "@"
    
    '２次元配列を作る
    cx = rg
    
    'ファイル読み込み
    With CreateObject("ADODB.Stream")
        .Type = 1 'adTypeBinary
        .Open
        .LoadFromFile fileName
        
        i = 1
        Do Until .EOS Or i > rowMax
            
            bf = .Read(readCount)
            
            '２バイト文字の割れ目調整(ファイルがShift_JISであると決め付け)
            If UBound(bf) = bufEnd Then
                If (bf(bufEnd) >= &H81 And bf(bufEnd) <= &H9F) Or (bf(bufEnd) >= &HE0 And bf(bufEnd) <= &HFF) Then
                    ReDim Preserve bf(bufEnd - 1) As Byte   '読み込んだバイト列の末尾を潰す
                    .Position = .Position - 1               'ファイルポインタを１バイト前へ
                End If
            End If
            
            cx(i, 1) = StrConv(bf, vbUnicode)
            i = i + 1
        Loop
        .Close
    End With
    
    '配列をセルに移す
    rg = cx
    
    Debug.Print Now()

End Sub

----

おまけ。個別に時間計測。

・セルに値を入れる時間

・StrConvの処理時間

Public Sub test2()
    
    '500バイトの文字列を65536個のセルに入れる処理
    Const dataCount As Long = 500
    Const rowMax As Long = 65536
    
    Dim i As Long
    Dim rg As Range
    Dim bf As String
    Dim cx As Variant
    
    Debug.Print Now()
    
    Application.ScreenUpdating = False
    
    Set rg = Worksheets(1).Range("A1:A" & rowMax)
    rg.Clear
    rg.NumberFormatLocal = "@"
    
    cx = rg
    
    bf = String(dataCount, "a")
    For i = 1 To rowMax
        cx(i, 1) = bf
    Next
    
    rg = cx
    
    Debug.Print Now()

End Sub

Public Sub test3()
    
    '500バイトを65536回StrConvで変換する処理
    Const dataCount As Long = 500
    Const rowMax As Long = 65536
    
    Dim i As Long
    Dim bf() As Byte
    Dim bf2 As String
    
    Debug.Print Now()
    
    bf = StrConv(String(dataCount, "a"), vbFromUnicode)
    For i = 1 To rowMax
        bf2 = StrConv(bf, vbUnicode)
    Next
    
    Debug.Print Now()

End Sub

http://q.hatena.ne.jp/1241755947