≪Access2000≫

もっとスマートな方法があるかもしれませんが、とりあえず結果を別テーブルに格納する例です。

テーブル２に結果を入れるので、このテーブルがすでにあるときはコード内のテーブル２を好きな

名前に変更してください。

Option Compare Database

Const TMP_TABLE = "テーブル2"   '★★★　結果テーブル名

Sub SELECT_ALL_01()
     Dim RS As DAO.Recordset
     
     readyTempTable
     
     Dim orderNum As String
     Dim productList As String
     
     Set RS = CurrentDb.OpenRecordset("SELECT * FROM テーブル1 ORDER BY 注文番号;")
     Do Until RS.EOF
        If RS!注文番号 <> orderNum Then
            If orderNum <> "" Then
                CurrentDb.Execute ("INSERT INTO " & TMP_TABLE & " ( 注文番号, 商品) VALUES ('" & orderNum & "','" & productList & "');")
            End If
            orderNum = RS!注文番号
            productList = RS!商品
        Else
            productList = productList & "," & RS!商品
        End If
        RS.MoveNext
    Loop
    If orderNum <> "" Then
        CurrentDb.Execute ("INSERT INTO " & TMP_TABLE & " ( 注文番号, 商品) VALUES ('" & orderNum & "','" & productList & "');")
    End If
    
'     DoCmd.RunSQL "SELECT * FROM " & TMP_TABLE & " ORDER BY [注文番号];"

    Set RS = Nothing
End Sub



Sub readyTempTable()
    Dim tbl As DAO.TableDef
    Dim str As String
  
    For Each tbl In CurrentDb.TableDefs
        If tbl.Name = TMP_TABLE Then
            CurrentDb.Execute ("DELETE FROM " & TMP_TABLE & ";")
            Exit Sub
        End If
    Next
    CurrentDb.Execute "CREATE TABLE " & TMP_TABLE & " ([注文番号] text(50), [商品] text(200) );"
End Sub

実行後、画面が更新されないことがあるかもしれませんが、F5キーを押して最新情報に更新してみてください。